Facebook 集成

class SocialMenu extends UDNMobileMenuScene;

/** 引用 Facebook 对象 */
var FacebookIntegration Facebook;

/** 我们要使用 facebook 进行验证吗？ */
var bool bIsFBAuthenticating;

/** 我们已经申请好友了吗（因为我们不希望每次想要查看他们的时候都发送申请）*/
var bool bFriendsListPopulated;

/**
 * 调用它初始化菜单并创建场景
 */
function InitMenuScene(MobilePlayerInput PlayerInput, int ScreenWidth, int ScreenHeight, bool bIsFirstInitialization)
{
   Super.InitMenuScene(PlayerInput, ScreenWidth, ScreenHeight, bIsFirstInitialization);

   //初始化列表
    List.InitMenuObject(PlayerInput, self, ScreenWidth, ScreenHeight, bIsFirstInitialization);

      //引用 Facebook 对象单例模式
   Facebook = class'PlatformInterfaceBase'.static.GetFacebookIntegration();

   //将代理设置为用于验证和 GraphAPI 请求回调（我们所使用不是网络请求）
   Facebook.AddDelegate(FID_AuthorizationComplete, OnFBAuthComplete);
   Facebook.AddDelegate(FID_FacebookRequestComplete, OnFBRequestComplete);

   //为我们的菜单对象（按钮、列表等等）创建一些代理
   UDNMobileMenuButton(FindMenuObject("Authorize")).OnClick = AuthorizeFacebook;
   UDNMobileMenuButton(FindMenuObject("Friends")).OnClick = RequestFriends;
   List.OnChange = OnSelectFriend;
   List.OnCancel = HideFriendsList;
}

/**
 * 在关闭菜单清理场景的时候进行调用
 */
function bool Closing()
{
   //在菜单关闭的时候清除所有代理
   Facebook.ClearDelegate(FID_AuthorizationComplete, OnFBAuthComplete);
   Facebook.ClearDelegate(FID_FacebookRequestComplete, OnFBRequestComplete);

   return super.Closing();
}

/**
 * 通过 "Authorize" 按钮的 OnClick 代理回调 - 执行 Facebook 验证过程
 *
 * 不使用这些参数 - 在这个实例中需要它们只是因为它与 UDNMobileMenuButton 的 OnClick 代理相匹配
 */
function AuthorizeFacebook(UDNMobileMenuObject Sender, float X, float Y)
{
   //我们以前已经验证过了吗？
   if (!Facebook.IsAuthorized())
   {
      //发送进行验证
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Not Authorized";
      if (Facebook.Authorize() == true)
      {
         UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Is Authorizing";
         bIsFBAuthenticating = true;
      }
   }
   else
   {
      //将状态设置为已验证
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Authorized";
   }
}

/**
 * 通过 "Friends" 按钮的 OnClick 代理回调 - 发送 Facebook GraphAPI 请求成为该用户的好友
 *
 * 不使用这些参数 - 在这个实例中需要它们只是因为它与 UDNMobileMenuButton 的 OnClick 代理相匹配
 */
function RequestFriends(UDNMobileMenuObject Sender, float X, float Y)
{
   //我们以前已经申请过好友了吗？
   if(!bFriendsListPopulated)
   {
      //向 graphAPI 发送申请获取好友列表
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Requesting Friends List";
      Facebook.FacebookRequest("me/friends");
   }
   else
   {
      //显示以前填充的好友列表
      List.bIsHidden = false;
   }
}

/**
 * 在选中一个选项后通过该列表回调 - 设置状态栏标签的文本并关闭列表。
 *
 * @item - 保存在列表中选中的好友的名称
 */
function OnSelectFriend(int Idx, string Item, float X, float Y)
{
   UDNMobileMenuLabel(FindMenuObject("Status")).Caption = item;
   list.bIsHidden=true;
}

/**
 * 在点击“cancel（取消）”按钮后通过列表回调 - 关闭列表
 */
function HideFriendsList()
{
   list.bIsHidden=true;
}

/**
 * 通过 Authorize() 回调
 *
 * @Result - 保存通过验证发送回来的数据
 */
function OnFBAuthComplete(const out PlatformInterfaceDelegateResult Result)
{
   //设置状态表明验证成功
   UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Auth Complete:"$Result.bSuccessful;
   bIsFBAuthenticating = false;
}

/**
 * 通过 GraphAPI 请求回调
 *
 * @Result - 保存通过该请求发送回来的数据
 */
function OnFBRequestComplete(const out PlatformInterfaceDelegateResult Result)
{
   local JsonObject Root, FriendsArray, Friend;
   local int Index;

   if (Result.bSuccessful)
   {
      //将状态设置为请求成功
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Request Successful";

      //通过该请求获取数据
      Root = class'JsonObject'.static.DecodeJson(Result.Data.StringValue);

      // 获取好友数列 - 最高级别是“data（数据）” = [friend,friend]
      FriendsArray = Root.GetObject("data");

      //将好友的数量输出到状态中
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "You have " $ FriendsArray.ObjectArray.length $ " friends:";

      // 在好友上循环
      for (Index = 0; Index < FriendsArray.ObjectArray.length; Index++)
      {
         // 获取一个好友对象
         Friend = FriendsArray.ObjectArray[Index];

         // 输出好友信息
         UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Friend " $ Friend.GetStringValue("name") $ " has ID " $ Friend.GetStringValue("id");

         //将新好友添加到该列表中
         List.AddItem(Friend.GetStringValue("name"));
      }

      //显示该列表
      List.bIsHidden = false;
      bFriendsListPopulated = true;
   }
   else
   {
      //将状态设置为请求未成功
      UDNMobileMenuLabel(FindMenuObject("Status")).Caption = "Facebook Request Unsuccessful";
   }
}

defaultproperties
{
   //验证按钮
   Begin Object Class=UDNMobileMenuButton Name=AuthorizeButton
      Tag="Authorize"
      Left=20
      Top=10
      Width=128
      Height=32
      TopLeeway=20
      Images(0)=Texture2D'PlatformInterfaceContent.fb_label'
        Images(1)=Texture2D'PlatformInterfaceContent.fb_label'
         ImagesUVs(0)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
         ImagesUVs(1)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
   End Object
   MenuObjects.Add(AuthorizeButton)

   //好友按钮
   Begin Object Class=UDNMobileMenuButton Name=FriendsButton
      Tag="Friends"
      Left=20
      Top=52
      Width=128
      Height=32
      TopLeeway=20
      TextFont=Font'EngineFonts.SmallFont'
      Images(0)=Texture2D'PlatformInterfaceContent.fb_friends'
        Images(1)=Texture2D'PlatformInterfaceContent.fb_friends'
         ImagesUVs(0)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
         ImagesUVs(1)=(bCustomCoords=true,U=0,V=0,UL=128,VL=32)
   End Object
   MenuObjects.Add(FriendsButton)

   //状态栏标签
    Begin Object class=UDNMobileMenuLabel name=Label0
      Tag="Status"
      Height=32
      Width=480
      Left=0
      Top=288
      TextFont=Font'EngineFonts.SmallFont'
      BackgroundColors(0)=(R=0.0,G=0.0,B=0.0,A=1.0)
      BackgroundColors(1)=(R=0.0,G=0.0,B=0.0,A=1.0)
      CaptionColors(0)=(R=1.0,G=1.0,B=1.0,A=1.0)
      CaptionColors(1)=(R=1.0,G=1.0,B=1.0,A=1.0)
      Caption="Status"
   End Object
   MenuObjects.Add(Label0)

   //好友列表
   Begin Object class=UDNMobileMenuList name=List0
      Tag="FriendsList"
      bIsHidden=true
      bHasCancel=true
      Title="Friends"
   End Object
   List=List0
}

class SocialPC extends SimplePC;

event InitInputSystem()
{
   Super.InitInputSystem();

   MPI.OpenMenuScene(class'SocialMenu');
}

defaultproperties
{
   InputClass=class'GameFramework.MobilePlayerInput'
}

class SocialGame extends SimpleGame;

defaultproperties
{
   PlayerControllerClass=class'UDNGame.SocialPC'
}