게임 센터 (Game Center)

[OnlineSubsystemGameCenter.OnlineSubsystemGameCenter]
bDisableGameCenter=false

[OnlineSubsystemGameCenter.OnlineSubsystemGameCenter]
bDisableGameCenter=false
UniqueAchievementPrefix=com.epicgames.exploreue3.achievement_
UniqueCategoryPrefix=com.epicgames.exploreue3.leaderboard_
EpicUniqueAchievementPrefix=com.epicgames.exploreue3.achievement_
EpicUniqueCategoryPrefix=com.epicgames.exploreue3.leaderboard_

[UnrealEd.EditorEngine]
+EditPackages=UTGame
+EditPackages=UTGameContent
+EditPackages=OnlineSubsystemGameCenter

class YourAchievementHandler extends Actor;

// 대기중인 업적
var array<int> PendingAchievements;
// 현재 업적을 처리중이면 참
var bool ProcessingAchievements;

/**
 * 플레이어의 업적을 풉니다.
 *
 * @param    AchievementId      풀 업적
 * @param    LocalUserNum      로컬 유저 인덱스
 */
function UnlockAchievement(int AchievementId)
{
  local OnlineSubsystem OnlineSubsystem;
  local int PlayerControllerId;

  // 이 업적은 이미 대기중으로 처리되고 있으니 그냥 기다립니다.
  if (PendingAchievements.Find(AchievementId) != INDEX_NONE)
  {
    return;
  }

  // 대기 목록에 업적 ID 를 추가합니다.
  PendingAchievements.AddItem(AchievementId);

  // 지금 업적을 처리중이지 않으면 처리합니다.
  if (!ProcessingAchievements)
  {
    // GameCenter 에 접속하여 업적 델리게이트를 연결합니다.
    OnlineSubsystem = class'GameEngine'.static.GetOnlineSubsystem();
    if (OnlineSubsystem != None && OnlineSubsystem.PlayerInterface != None)
    {
      // 로컬 플레이어 콘트롤러 ID 를 구합니다.
      PlayerControllerId = GetALocalPlayerControllerId();

      // 업적 읽기 델리게이트를 할당합니다.
      OnlineSubsystem.PlayerInterface.AddReadAchievementsCompleteDelegate(PlayerControllerId, InternalOnReadAchievementsComplete);

      // 모든 업적을 읽습니다.
      OnlineSubsystem.PlayerInterface.ReadAchievements(PlayerControllerId);

      // 참으로 설정하여 다시 발동되지 않도록 합니다.
      ProcessingAchievements = true;
    }
  }
}

/**
 * 로컬 플레이어 콘트롤러 ID 를 반환합니다. 같은 규칙이 Actor::GetALocalPlayerController() 에 적용됩니다.
 *
 * @return    로컬 플레이어 콘트롤러 ID 를 반환
 */
function int GetALocalPlayerControllerId()
{
  local PlayerController PlayerController;
  local LocalPlayer LocalPlayer;

  // 로컬 플레이어 콘트롤러를 구합니다.
  PlayerController = GetALocalPlayerController();
  if (PlayerController == None)
  {
    return INDEX_NONE;
  }

  // 로컬 플레이어 정보를 구합니다.
  LocalPlayer = LocalPlayer(PlayerController.Player);
  if (LocalPlayer == None)
  {
    return INDEX_NONE;
  }

  return class'UIInteraction'.static.GetPlayerIndex(LocalPlayer.ControllerId);
}

class YourAchievementHandler extends Actor;

// 모든 내려받은 업적 배열
var array<AchievementDetails> DownloadedAchievements;

/**
 * 비동기 업적 읽기 완료시 호출됩니다.
 *
 * @param    TitleId      읽고 있던 것에 해당하는 타이틀 ID (0 은 현재 타이틀)
 */
function InternalOnReadAchievementsComplete(int TitleId)
{
  local OnlineSubsystem OnlineSubsystem;
  local int AchievementIndex, PlayerControllerId;

  // 온라인 서브시스템이 있는지, 연결된 플레이어 인터페이스가 있는지 확인합니다.
  OnlineSubsystem = class'GameEngine'.static.GetOnlineSubsystem();
  if (OnlineSubsystem == None || OnlineSubsystem.PlayerInterface == None)
  {
    return;
  }

  // 로컬 플레이어 콘트롤러 ID 를 구합니다.
  PlayerControllerId = GetALocalPlayerControllerId();

  // 새로운 데이터를 복사할 것이기에 현재 다운받은 업적 배열을 비웁니다.
  DownloadedAchievements.Remove(0, DownloadedAchievements.Length);

  // 다운받은 업적 배열에 업적을 읽어들입니다.
  OnlineSubsystem.PlayerInterface.GetAchievements(PlayerControllerId, DownloadedAchievements, TitleId);

  // 모든 업적을 구합니다.
  if (DownloadedAchievements.Length > 0 && PendingAchievements.Length > 0)
  {
    // 업적 인덱스를 구합니다.
    AchievementIndex = DownloadedAchievements.Find('Id', PendingAchievements[0]);

    // 업적을 풉니다.
    if (AchievementIndex != INDEX_NONE && !DownloadedAchievements[AchievementIndex].bWasAchievedOnline)
    {
      // 업적 풀기 완료 델리게이트를 할당합니다.
      OnlineSubsystem.PlayerInterface.AddUnlockAchievementCompleteDelegate(PlayerControllerId, InternalOnUnlockAchievementComplete);

      // 풀기 프로세스를 시작합니다.
      OnlineSubsystem.PlayerInterface.UnlockAchievement(PlayerControllerId, PendingAchievements[0]);
    }
  }

  // 가비지 콜렉션이 일어나도록 델리게이트 리퍼런스를 제거합니다.
  OnlineSubsystem.PlayerInterface.ClearReadAchievementsCompleteDelegate(PlayerControllerId, InternalOnReadAchievementsComplete);
}

class YourAchievementHandler extends Actor;

/**
 * 업적 풀기가 완료되면 호출됩니다.
 *
 * @param bWasSuccessful 비동기 동작이 에러없이 끝나면 참, 에러가 있었으면 거짓
 */
function InternalOnUnlockAchievementComplete(bool bWasSuccessful)
{
  local OnlineSubsystem OnlineSubsystem;
  local PlayerController PlayerController;
  local int AchievementIndex, PlayerControllerId;

  // 로컬 플레이어 콘트롤러 ID 를 구합니다.
  PlayerControllerId = GetALocalPlayerControllerId();

  if (bWasSuccessful && PendingAchievements.Length > 0)
  {
    // 로컬 플레이어 콘트롤러를 구합니다.
    PlayerController = GetALocalPlayerController();
    if (PlayerController != None)
    {
      // 업적 인덱스를 구합니다.
      AchievementIndex = DownloadedAchievements.Find('Id', PendingAchievements[0]);

      // 플레이어의 유저 인터페이스에 업적을 표시합니다.
    }
  }

  // 성공 여부와 관계없이 처리한 업적을 뽑아냅니다.
  PendingAchievements.Remove(0, 1);

  // 온라인 서브시스템이 있는지, 연결된 플레이어 인터페이스가 있는지 확인합니다.
  OnlineSubsystem = class'GameEngine'.static.GetOnlineSubsystem();
  if (OnlineSubsystem == None || OnlineSubsystem.PlayerInterface == None)
  {
    return;
  }

  // 대기중인 업적이 남아있으면 다음 것을 처리합니다.
  if (PendingAchievements.Length > 0)
  {
    // 게임센터에 접속하여 업적 델리게이트를 연결합니다.
    // 업적 읽기 델리게이트를 할당합니다.
    OnlineSubsystem.PlayerInterface.AddReadAchievementsCompleteDelegate(PlayerControllerId, InternalOnReadAchievementsComplete);

    // 모든 업적을 읽습니다.
    OnlineSubsystem.PlayerInterface.ReadAchievements(PlayerControllerId);
  }
  else // 아니면 끝난 것이니 정리합니다.
  {
    // 델리게이트 바인드를 지웁니다.
    OnlineSubsystem.PlayerInterface.ClearUnlockAchievementCompleteDelegate(PlayerControllerId, InternalOnUnlockAchievementComplete);

    // 더이상 업적을 처리하지 않는 상태로 플랙 설정합니다.
    ProcessingAchievements = false;
  }
}

class YourAchievementHandler extends Actor;

/**
 * 액터 소멸시 호출됩니다.
 */
event Destroyed()
{
  local OnlineSubsystem OnlineSubsystem;
  local int PlayerControllerId;

  Super.Destroyed();

  // 온라인 서브시스템이 있는지, 연결된 플레이어 인터페이스가 있는지 확인합니다.
  OnlineSubsystem = class'GameEngine'.static.GetOnlineSubsystem();
  if (OnlineSubsystem == None || OnlineSubsystem.PlayerInterface == None)
  {
    return;
  }

  // 아직 업적을 처리중이라면, 가비지 콜렉션이 일어날 수 있도록 할당된 델리게이트를 지워야 합니다.
  if (ProcessingAchievements)
  {
    // 로컬 플레이어 콘트롤러 ID 를 구합니다.
    PlayerControllerId = GetALocalPlayerControllerId();

    // 가비지 콜렉션이 일어날 수 있도록 델리게이트 리퍼런스를 지웁니다.
    OnlineSubsystem.PlayerInterface.ClearReadAchievementsCompleteDelegate(PlayerControllerId, InternalOnReadAchievementsComplete);

    // 델리게이트 바인드를 지웁니다.
    OnlineSubsystem.PlayerInterface.ClearUnlockAchievementCompleteDelegate(PlayerControllerId, InternalOnUnlockAchievementComplete);
    }
  }

class YourOnlineStatsWrite extends OnlineStatsWrite;

const PROPERTY_KILLS = 1;
const PROPERTY_LEVEL = 2;
const PROPERTY_GOLD = 3;

defaultproperties
{
   Properties=((PropertyId=PROPERTY_KILLS,Data=(Type=SDT_Int32,Value1=0)),(PropertyId=PROPERTY_LEVEL,Data=(Type=SDT_Int32,Value1=0)),(PropertyId=PROPERTY_GOLD,Data=(Type=SDT_Int32,Value1=0)))
}

local OnlineSubsystem OnlineSubsystem;
local OnlineSuppliedUIInterface OnlineSuppliedUIInterface;
local array<UniqueNetId> PlayerIds;
local UniqueNetId PlayerId;
local YourOnlineStatsRead YourOnlineStatsRead;
local PlayerController PlayerController;
local LocalPlayer LocalPlayer;
local byte LocalUserNum;

// 온라인 서브 시스템을 구합니다.
OnlineSubSystem = class'GameEngine'.static.GetOnlineSubsystem();
// 온라인 서브 시스템에 접근할 수 있는지 확인합니다.
if (OnlineSubSystem != None)
{
  // 로컬 플레이어 콘트롤러에서 PlayerIds 배열을 만듭니다.
  PlayerController = GetALocalPlayerController();
  if (PlayerController != None)
  {
    // 로컬 플레이어를 구합니다.
    LocalPlayer = LocalPlayer(PlayerController.Player);
    if (LocalPlayer != None)
    {
      // 로컬 사용자 번호를 구합니다.
      LocalUserNum = class'UIInteraction'.static.GetPlayerIndex(LocalPlayer.ControllerId);
      // 로컬 사용자 번호에서 고유 플레이어 id 를 구합니다.
      OnlineSubSystem.PlayerInterface.GetUniquePlayerId(LocalUserNum, PlayerId);
      // 고유 플레이어 id 를 PlayerIds 배열에 추가합니다.
      PlayerIds.AddItem(PlayerId);

      // 온라인 제공 UI 인터페이스를 구합니다.
      OnlineSuppliedUIInterface = OnlineSuppliedUIInterface(OnlineSubSystem.GetNamedInterface('SuppliedUI'));
      if (OnlineSuppliedUIInterface != None)
      {
        // 온라인 통계 읽기 클래스 인스턴싱 입니다.
        YourOnlineStatsRead = new () class'YourOnlineStatsRead';
        if (YourOnlineStatsRead!= None)
        {
          // 온라인 통계 UI 를 표시합니다.
          OnlineSuppliedUIInterface.ShowOnlineStatsUI(PlayerIds, YourOnlineStatsRead);
        }
      }
    }
  }
}

class YourOnlineStatsRead extends OnlineStatsRead;

const PROPERTY_KILLS = 1;
const PROPERTY_LEVEL = 2;
const PROPERTY_GOLD = 3;

defaultproperties
{
   ColumnIds=(PROPERTY_KILLS,PROPERTY_LEVEL,PROPERTY_GOLD)
}

   OnlineSuppliedUIInterface(OnlineSub.GetNamedInterface('SuppliedUI')).ShowMatchmakingUI();